1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
|
;;; gnosis-algorithm.el --- Spaced Repetition Algorithm for Gnosis -*- lexical-binding: t; -*-
;; Copyright (C) 2023-2024 Thanos Apollo
;; Author: Thanos Apollo <[email protected]>
;; Keywords: extensions
;; URL: https://git.thanosapollo.org/gnosis
;; Version: 0.0.1
;; Package-Requires: ((emacs "27.2") (compat "29.1.4.2"))
;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <https://www.gnu.org/licenses/>.
;;; Commentary:
;; Module that handles date and interval calculation as well as
;; gnosis-score for gnosis.
;;; Code:
(require 'cl-lib)
(require 'calendar)
(defcustom gnosis-algorithm-proto '(0 1 2)
"Gnosis proto interval for the first successful reviews.
Values for the first proto successful intervals. There is no
restriction for list length."
:group 'gnosis
:type '(list integer))
(defcustom gnosis-algorithm-gnosis-value '(0.35 0.30 1.3)
"Starting gnosis score.
First item : Increase value (gnosis-plus)
Second item: Decrease value (gnosis-minus)
Third item : Total gnosis (gnosis-synolon/totalis) -> Total gnosis score"
:group 'gnosis
:type '(list float))
(defcustom gnosis-algorithm-amnesia-value 0.5
"Gnosis amnesia value.
Used to calcuate new interval upon a failed recall i.e the memmory loss.
The closer this value is to 1, the more the memory loss."
:group 'gnosis
:type 'float)
(defcustom gnosis-algorithm-epignosis-value 0.1
"Value to increase gnosis-plus upon anagnosis.
Epignosis means knowledge accuracy."
:group 'gnosis
:type 'float)
(defcustom gnosis-algorithm-agnoia-value 0.2
"Value to increase gnosis-minus upon anagnosis.
Agnoia refers to the lack of knowledge."
:group 'gnosis
:type 'float)
(defcustom gnosis-algorithm-anagnosis-value 3
"Threshold value for anagnosis event.
Anagosis is the process recognition & understanding of a context/gnosis.
Anagnosis events update gnosis-plus & gnosis-minus values, depending
on the success or failure of recall."
:group 'gnosis
:type 'integer)
(defcustom gnosis-algorithm-lethe-value 2
"Threshold value for hitting a lethe event.
Lethe is the process of being unable to recall a memory/gnosis.
On lethe events the next interval is set to 0."
:group 'gnosis
:type 'integer)
(defun gnosis-algorithm-replace-at-index (index new-item list)
"Replace item at INDEX with NEW-ITEM in LIST."
(cl-loop for item in list
for i from 0
collect (if (= i index) new-item item)))
(defun gnosis-algorithm-round-items (list)
"Round all items in LIST to 2 decimal places."
(cl-loop for item in list
collect (/ (round (* item 100)) 100.0)))
(defun gnosis-algorithm-date (&optional offset)
"Return the current date in a list (year month day).
Optional integer OFFSET is a number of days from the current date."
(cl-assert (or (integerp offset) (null offset)) nil "Date offset must be an integer or nil")
(let* ((base-time (current-time))
(target-time (if offset
(time-add base-time (days-to-time offset))
base-time))
(decoded-time (decode-time target-time)))
(list (decoded-time-year decoded-time)
(decoded-time-month decoded-time)
(decoded-time-day decoded-time))))
(defun gnosis-algorithm-date-diff (date &optional date2)
"Find the difference between DATE2 and DATE.
If DATE2 is nil, current date will be used instead.
DATE format must be given as (year month day)."
(let* ((given-date (encode-time 0 0 0 (caddr date) (cadr date) (car date)))
(date2 (if date2 (encode-time 0 0 0 (caddr date2) (cadr date2) (car date2))
(current-time)))
(diff (- (time-to-days date2)
(time-to-days given-date))))
(if (>= diff 0) diff (error "`DATE2' must be higher than `DATE'"))))
(cl-defun gnosis-algorithm-next-gnosis (&key gnosis success epignosis agnoia anagnosis
c-successes c-failures)
"Return the neo GNOSIS value. (gnosis-plus gnosis-minus gnsois-synolon)
Calculate the new e-factor given existing GNOSIS and SUCCESS, either t or nil.
Next GNOSIS is calculated as follows:
Upon a successful review, increase gnosis-synolon value (nth 2 gnosis) by
gnosis-plus value (nth 0 gnosis).
Upon a failed review, decrease gnosis-synolon by gnosis-minus value
(nth 1 gnosis).
ANAGNOSIS is an event threshold, updating either the gnosis-plus or
gnosis-minus values.
When C-SUCCESSES (consecutive successes) reach ANAGNOSIS,
increase gnosis-plus by EPIGNOSIS.
When C-FAILURES reach ANAGOSNIS, increase gnosis-minus by AGNOIA."
(cl-assert (listp gnosis) nil "Assertion failed: gnosis must be a list of floats.")
(cl-assert (booleanp success) nil "Assertion failed: success must be a boolean value")
(cl-assert (and (floatp epignosis) (< epignosis 1)) nil "Assertion failed: epignosis must be a float < 1")
(cl-assert (and (floatp agnoia) (< agnoia 1)) nil "Assertion failed: agnoia must be a float < 1")
(cl-assert (integerp anagnosis) nil "Assertion failed: anagosis must be an integer.")
(let ((anagnosis-p (= (% (max 1 (if success c-successes c-failures)) anagnosis) 0))
(neo-gnosis
(if success
(gnosis-algorithm-replace-at-index 2 (+ (nth 2 gnosis) (nth 0 gnosis)) gnosis)
(gnosis-algorithm-replace-at-index 2 (max 1.3 (- (nth 2 gnosis) (nth 1 gnosis))) gnosis))))
;; TODO: Change amnesia & epignosis value upon reaching a lethe or anagnosis event.
(cond ((and success anagnosis-p)
(setf neo-gnosis (gnosis-algorithm-replace-at-index 0 (+ (nth 0 gnosis) epignosis) neo-gnosis)))
((and (not success) anagnosis-p
(setf neo-gnosis
(gnosis-algorithm-replace-at-index 1 (+ (nth 1 gnosis) agnoia) neo-gnosis)))))
(gnosis-algorithm-round-items neo-gnosis)))
(cl-defun gnosis-algorithm-next-interval (&key last-interval gnosis-synolon success successful-reviews
amnesia proto c-fails lethe)
"Calculate next interval.
LAST-INTERVAL: Number of days since last review
C-FAILS: Total consecutive failed reviews.
GNOSIS-SYNOLON: Current gnosis-synolon (gnosis totalis).
SUCCESS: non-nil when review was successful.
SUCCESSFUL-REVIEWS: Number of successful reviews.
AMNESIA: 'Forget value', used to calculate next interval upon failed
review.
PROTO: List of proto intervals, for successful reviews.
Until successfully completing proto reviews, for every failed attempt
the next interval will be set to 0.
LETHE: Upon having C-FAILS >= lethe, set next interval to 0."
(cl-assert (booleanp success) nil "Success value must be a boolean")
(cl-assert (integerp successful-reviews) nil "Successful-reviews must be an integer")
(cl-assert (and (floatp amnesia) (<= amnesia 1)) nil "Amnesia must be a float <=1")
(cl-assert (and (<= amnesia 1) (> amnesia 0)) nil "Value of amnesia must be a float <= 1")
(cl-assert (and (integerp lethe) (>= lethe 1)) nil "Value of lethe must be an integer >= 1")
;; This should only occur in testing env or when the user has made breaking changes.
(let* ((last-interval (if (<= last-interval 0) 1 last-interval)) ;; If last-interval is 0, use 1 instead.
(amnesia (- 1 amnesia)) ;; inverse amnesia
(interval (cond ((and (< successful-reviews (length proto))
success)
(nth successful-reviews proto))
;; Lethe event, reset interval.
((and (>= c-fails lethe)
(not success))
0)
(t (let* ((success-interval (* gnosis-synolon last-interval))
(failure-interval (* amnesia last-interval)))
(if success success-interval
;; Make sure failure interval is never
;; higher than success and at least 0
(max (min success-interval failure-interval) 0)))))))
(gnosis-algorithm-date (round interval))))
(provide 'gnosis-algorithm)
;;; gnosis-algorithm.el ends here
|
